#################################################################################

# SAVE THE FILE WITH THE EXTENSION .ODE PRIOR TO RUNNING IT IN XPP

# BELOW IS THE ODE FILE ACCOMPANYING THE MANUSCRIPT "POTENTIAL ROLE OF BISTABLE HISTIDINE # KINASE IN ASYMMETRIC DIVISION CYCLE OF CAULOBACTER CRESCENTUS"

#  THE PARAMETERS ARE FOR SIMULATING THE ** WILD TYPE **

# AUTHORS: KARTIK SUBRAMANIAN	
#          MARK PAUL
#	   JOHN TYSON
# DATE:	   APRIL 2013	

##################################################################################	

#### PARAMETERS ###########

param divj_tot=0.5,	ksyn_dk=0.015,	plec_tot=1

param kdeg_dk=0.005,	kdeg_dkp=0.005

param kj_jk=1,	kjk_j=0.1,	ke_jkin=0.5

param kpc_ph1=5,	kph1_pc=5

param kph1_ph11=5,	kph11_ph1=5

param kh11_pk11=5,	kpk11_h11=5

param kpk11_pk0=5,	kpk0_pk11=5

param kpk0_pk1=0.16,	kpk1_pk0=5

param kpk1_pk2=5,	kpk2_pk1=0.0016

param kpk1_pk1h=5,	kpk1h_pk1=5

param kpk1_pk2p=0.16,	kpk2p_pk1=5

param kpk2_pt2=5,	kpt2_pk2=0.16

param kpt2_pk1h=0.16,	kpk1h_pt2=5

param kpk2p_h2p=5,	kh2p_pk2p=0.005

param kph2p_pc=5,	kh1p_pc=5

param kpk2_pk3=0.16,	kpk3_pk2=5

param kpk3_pt3=5,	kpt3_pk3=0.16

param kpt3_pk1p=0.16,	kpk1p_pt3=5

param kpk1p_1h=5,	k1h_pk1p=0.16

param kpk1p_h1p=5,	kh1p_pk1p=0.005

param kpk3_pk2p=0.0016,	kpk2p_pk3=5

param kpk3_pk4=5,	kpk4_pk3=0.0016

param kpk4_pt4=5,	kpt4_pk4=0.15

param kpt4_pk11=5,	kpk11_pt4=0.16

param kpc_ph2=0.05,	kph2_pc=5

param kph2_ph22=0.05,	kph22_ph2=5

param kh22_pk22=5,	kpk22_h22=5e-08

param kpk22_pk4=5,	kpk4_pk22=5

param kph2_ph12=5,	kph12_ph2=5

param kph1_ph12=0.05,	kph12_ph1=5

param kh12_pk12=5,	kpk12_h12=5e-04

param kpk12_pk2=5,	kpk2_pk12=5

param kpch_pck=0.005,	kpck_pch=5

param kpck_pkdk=5,	kpkdk_pck=0.0016

param kpdk_pk22=5,	kpk22_pdk=0.0016

param kpdk_pk12=5,	kpk12_pdk=0.16

param kpck_pt3h=5,	kpt3h_pck=0.16

param kt3h_pk11=5,	kpk11_t3h=0.16

param kt3h_pk12=5,	kpk12_t3h=0.0016

param kpt4_pk3h=0.16,	kpk3h_pt4=5

param kpk3_pk3h=5,	kpk3h_pk3=5

param kpk1p_p3h=5,	kp3h_pk1p=0.0016

param kp3h_pt3h=5,	kpt3h_p3h=0.16


param ksyn_pld=0.01,	kdeg_pld=0.005,	kdeg_pldp=0.005

param kpk1_pk5=10,	kpk5_pk1=0.31

param kpk5_pt5=10,	kpt5_pk5=0.31

param kpt5_pk1h=10,	kpk1h_pt5=0.31

param kpk3_pk6=10,	kpk6_pk3=0.31

param kpk6_pt6=10,	kpt6_pk6=0.31

param kpt6_pk3h=10,	kpk3h_pt6=0.31

param phos_tot=0.1,	kphos_ph3=1,	kph3_phos=0.1,	ke_ph3=0.2

param kpld_pld2=0,	kpld2_pld=0.1,	kdeg_pld2=0.04

#param kph1_ph2=2,	kph2_ph1=1

param kph1_ph2=10,	kph2_ph1=5e-03

param kph1_pk1=0.0001,	kpk1_ph1=0.01,	kph2_pk2=0.01,	kpk2_ph2=0.0001

param divl_tot=1,	kbdl_dldk=1,	kudl_dldk=0.1 
 
param ksyndl=0.005,	kdegdl=0.005

################# EQUATIONS ################

dDIVKP/dt = -kdeg_dkp*DIVKP -kpc_ph1*PLEC*DIVKP + kph1_pc*PLECH1  -kph1_ph11*PLECH1*DIVKP + kph11_ph1*PH11 + kpk0_pk1*PK0 -  kpk1_pk0*PK1*DIVKP + kpk1_pk2p*PK1 - kpk2p_pk1*PK2P*DIVKP + kpt2_pk1h*PT2 - kpk1h_pt2*PK1H*DIVKP + ke_jkin*JK + kpk2_pk3*PK2 - kpk3_pk2*PK3*DIVKP + kpt3_pk1p*PT3 - kpk1p_pt3*PK1P*DIVKP - kpk1p_1h*PK1p*DIVKP + k1h_pk1p*PK1H - kph2_ph12*PLECH2*DIVKP + kph12_ph2*PH12  - kpck_pt3h*PLECKIN*DIVKP +kpt3h_pck*PT3H - kpdk_pk12*PKDK*DIVKP + kpk12_pdk*PK12 - kt3h_pk11*PT3H*DIVKP + kpk11_t3h*PK11+ kpt4_pk3h*PT4 - kpk3h_pt4*PK3H*DIVKP  - kbdl_dldk*divl*divkp + kudl_dldk*dldk
 
dDIVK/dt = ksyn_dk - kdeg_dk*DIVK  - kpk1_pk2*PK1*DIVK + kpk2_pk1*PK2 -kj_jk*DIVJ*DIVK + kjk_j*JK + kpk3_pk2p*PK3 - kpk2p_pk3*PK2P*DIVK - kpk3_pk4*PK3*DIVK + kpk4_pk3*PK4 - kpc_ph2*PLEC*DIVK + kph2_pc*PLECH2 - kph2_ph22*PLECH2*DIVK + kph22_ph2*Ph22- kph1_ph12*PLECH1*DIVK + kph12_ph1*PH12  - kpck_pkdk*PLECKIN*DIVK + kpkdk_pck*PKDK - kpdk_pk22*PKDK*DIVK + kpk22_pdk*PK22 - kt3h_pk12*PT3H*DIVK + kpk12_t3h*PK12 - kpk1p_p3h*PK1P*DIVK + kp3h_pk1p*PK3H


dDIVJ/dt = -kj_jk*DIVJ*DIVK + kjk_j*JK + ke_jkin*JK

#djk/dt =  kj_jk*DIVJ*DIVK - kjk_j*JK - ke_jkin*JK

#dPleC/dt = - kpc_ph1*PLEC*DIVKP + kph1_pc*PLECH1  + kph2p_pc*PH2P +  kh1p_pc*PH1P - kpc_ph2*PLEC*DIVK + kph2_pc*PLECH2


dPLECH1/dt =  kpc_ph1*PLEC*DIVKP - kph1_pc*PLECH1 -kph1_ph11*PLECH1*DIVKP + kph11_ph1*PH11  - kph1_ph12*PLECH1*DIVK + kph12_ph1*PH12 - kph1_ph2*PLECH1 + kph2_ph1*PLECH2 - kph1_pk1*plech1 +kpk1_ph1*pt3h

dPH11/dt = kph1_ph11*PLECH1*DIVKP - kph11_ph1*PH11 - kh11_pk11*PH11 + kpk11_h11*PK11 

dPK11/dt =  kh11_pk11*Ph11 - kpk11_h11*PK11 - kpk11_pk0*PK11 +  kpk0_pk11*PK0 + kpt4_pk11*pt4 - kpk11_pt4*pk11 + kt3h_pk11*PT3H*DIVKP - kpk11_t3h*PK11

dPK0/dt = kpk11_pk0*PK11 - kpk0_pk11*pk0 - kpk0_pk1*PK0 + kpk1_pk0*PK1*DIVKP

dPK1/dt =  kpk0_pk1*PK0 -  kpk1_pk0*PK1*DIVKP  - kpk1_pk2*PK1*DIVK + kpk2_pk1*PK2 - kpk1_pk2p*PK1 + kpk2p_pk1*PK2P*DIVKP -  kpk1_pk1h*PK1 + kpk1h_pk1*PK1H - kpk1_pk5*PK1*PLED +  kpk5_pk1*PK5

dPK2/dt =  kpk1_pk2*PK1*DIVK - kpk2_pk1*PK2 -kpk2_pt2*PK2 + kpt2_pk2*PT2 - kpk2_pk3*PK2 + kpk3_pk2*PK3*DIVKP + kpk12_pk2*PK12 - kpk2_pk12*PK2

dPT2/dt = kpk2_pt2*PK2 - kpt2_pk2*PT2 -kpt2_pk1h*PT2 + kpk1h_pt2*PK1H*DIVKP

dPK1H/dt =  kpt2_pk1h*PT2 - kpk1h_pt2*PK1H*DIVKP + kpk1_pk1h*PK1 - kpk1h_pk1*PK1H + kpk1p_1h*PK1p*DIVKP - k1h_pk1p*PK1H - kpk1h_pt5*PK1h*PLeDp + kpt5_pk1h*PT5

dPK2P/dt = kpk1_pk2p*PK1 - kpk2p_pk1*PK2P*DIVKP - kpk2p_h2p*PK2P + kh2p_pk2p*PH2P + kpk3_pk2p*PK3 - kpk2p_pk3*PK2P*DIVK 

dPH2P/dt =  kpk2p_h2p*PK2P - kh2p_pk2p*PH2P - kph2p_pc*PH2P

########################################################

dPK3/dt = kpk2_pk3*PK2 - kpk3_pk2*PK3*DIVKP -  kpk3_pt3*PK3 + kpt3_pk3*PT3 - kpk3_pk2p*PK3 + kpk2p_pk3*PK2P*DIVK - kpk3_pk4*PK3*DIVK + kpk4_pk3*PK4 - kpk3_pk3h*PK3 + kpk3h_pk3*PK3H - kpk3_pk6*PK3*PLED +  kpk6_pk3*PK6

dPT3/dt = kpk3_pt3*PK3 - kpt3_pk3*PT3 + kpk1p_pt3*PK1P*DIVKP - kpt3_pk1p*PT3

dPK1P/dt = kpt3_pk1p*PT3 - kpk1p_pt3*PK1P*DIVKP -kpk1p_1h*PK1p*DIVKP + k1h_pk1p*PK1H - kpk1p_h1p*PK1P +kh1p_pk1p*PH1P - kpk1p_p3h*PK1P*DIVK +kp3h_pk1p*PK3H

dPH1P/dt = kpk1p_h1p*PK1P - kh1p_pk1p*PH1P - kh1p_pc*PH1P

########################################################

dPK4/dt = kpk3_pk4*PK3*DIVK - kpk4_pk3*PK4 - kpk4_pt4*PK4 + kpt4_pk4*PT4 + kpk22_pk4*PK22 - kpk4_pk22*PK4

dPT4/dt = kpk4_pt4*PK4 - kpt4_pk4*PT4 - kpt4_pk11*pt4 + kpk11_pt4*pk11- kpt4_pk3h*PT4 + kpk3h_pt4*PK3H*DIVKP

#################################################################

dPLECH2/dt = kpc_ph2*PLEC*DIVK - kph2_pc*PLECH2 - kph2_ph22*PLECH2*DIVK + kph22_ph2*Ph22- kph2_ph12*PLECH2*DIVKP + kph12_ph2*PH12 + kph1_ph2*PLECH1 - kph2_ph1*PLECH2 - kph2_pk2*plech2 + kpk2_ph2*pkdk

dPH22/dt =  kph2_ph22*PLECH2*DIVK - kph22_ph2*PH22 - kh22_pk22*PH22 + kpk22_h22*PK22  

dPK22/dt =  kh22_pk22*PH22 - kpk22_h22*PK22 - kpk22_pk4*PK22 + kpk4_pk22*PK4 + kpdk_pk22*PKDK*DIVK - kpk22_pdk*PK22

#################################################################

dPH12/dt= kph2_ph12*PLECH2*DIVKP - kph12_ph2*PH12 + kph1_ph12*PLECH1*DIVK - kph12_ph1*PH12 - kh12_pk12*PH12 + kpk12_h12*PK12 

dPK12/dt=kh12_pk12*PH12 - kpk12_h12*PK12 - kpk12_pk2*PK12 + kpk2_pk12*PK2 + kpdk_pk12*PKDK*DIVKP - kpk12_pdk*Pk12 + kt3h_pk12*PT3H*DIVK -kpk12_t3h*PK12

#################################################################

dPLECKIN/dt = kpch_pck*PLEC - kpck_pch*PLECKIN - kpck_pt3h*PLECKIN*DIVKP +kpt3h_pck*PT3H - kpck_pkdk*PLECKIN*DIVK + kpkdk_pck*PKDK

dPKDK/dt = kpck_pkdk*PLECKIN*DIVK - kpkdk_pck*PKDK - kpdk_pk22*PKDK*DIVK + kpk22_pdk*PK22 - kpdk_pk12*PKDK*DIVKP + kpk12_pdk*Pk12 +kph2_pk2*Plech2 - kpk2_ph2*pkdk

dPT3H/dt = kpck_pt3h*PLECKIN*DIVKP - kpt3h_pck*PT3H - kt3h_pk11*PT3H*DIVKP + kpk11_t3h*PK11 - kt3h_pk12*PT3H*DIVK + kpk12_t3h*PK12 + kp3h_pt3h*PK3H - kpt3h_p3h*PT3H + kph1_pk1*plech1 - kpk1_ph1*pt3h

#################################################################

dPK3H/dt = kpt4_pk3h*PT4 - kpk3h_pt4*PK3H*DIVKP + kpk3_pk3h*PK3 - kpk3h_pk3*PK3H + kpk1p_p3h*PK1P*DIVK - kp3h_pk1p*PK3H - kp3h_pt3h*PK3H + kpt3h_p3h*PT3H + kpt6_pk3h*PT6 - kpk3h_pt6*PK3H*PLEDP

################################################

dPLED/dt = ksyn_pld - kdeg_pld*PLED - kpk1_pk5*PK1*PLED + kpk5_pk1*PK5 - kpk3_pk6*PK3*PLED + kpk6_pk3*PK6 + ke_ph3*PH3

dPLEDP/dt =  - kdeg_pldp*PLEDP + kpt5_pk1h*PT5 - kpk1h_pt5*PK1H*PLEDP + kpt6_pk3h*PT6 -kpk3h_pt6*PK3H*PLEDP  - kphos_ph3*PHOS*PLEDP + kph3_phos*PH3 
#- kpld_pld2*PLEDP*PLEDP #+ kpld2_pld*Pled2 + kdeg_pld2*pled2

dPK5/dt =  kpk1_pk5*PK1*PLED -  kpk5_pk1*PK5 - kpk5_pt5*PK5 + kpt5_pk5*PT5

dPK6/dt =  kpk3_pk6*PK3*PLED -  kpk6_pk3*PK6 - kpk6_pt6*PK6 + kpt6_pk6*PT6

dPT5/dt = kpk5_pt5*PK5 - kpt5_pk5*PT5 - kpt5_pk1h*PT5 + kpk1h_pt5*PK1H*PLEDP

dPT6/dt = kpk6_pt6*PK6 - kpt6_pk6*PT6 - kpt6_pk3h*PT6 + kpk3h_pt6*PK3H*PLEDP

dPHOS/dt = - kphos_ph3*PHOS*PLEDP + kph3_phos*PH3 + ke_ph3*PH3
 
# dPH3/dt = kphos_ph3*PHOS*PLEDP - kph3_phos*PH3 - ke_ph3*PH3

dPled2/dt = kpld_pld2*PLEDP*PLEDP - kpld2_pld*Pled2 - kdeg_pld2*pled2

dDIVL/dt = ksyndl - kdegdl*DIVL- kbdl_dldk*DIVL*DIVKP + kudl_dldk*DLDK 

ddldk/dt = kbdl_dldk*divl*divkp - kudl_dldk*dldk -kdegdl*dldk

#################################################################

# pleckint = total kinase 
dPLECKINT/dt=pleckinase-PLECKINT

# plecdivk = divk bound plec
dplecdk/dt = plecdivk-plecdk

#### conservation rule ######

PLEC = -((PLECH1+PH11+ PK11 +PK1+PK2+PK0+PK1H + PT2 +PK2P +PH2P+ pk3+ pt3 + pk1p+ph1p +pk4 +pt4+plech2+ph22+pk22+pk12+ph12+pleckin + pkdk + pt3h+pk3h+pk5+pt5+pk6+pt6) - plec_tot)
aux PLEC=PLEC

jk = -(divj-divj_tot)
aux jk = jk

pleckinase=(PK11 +PK1+PK2+PK0+PK1H + PT2 +PK2P + pk3+ pt3 + pk1p +pk4 +pt4+pk22+pk12+pleckin + pkdk + pt3h+pk3h+pk5+pt5+pk6+pt6)
aux pleckinase=pleckinase

plecdivk= (PLECH1+PH11+ PK11 +PK1+PK2+PK0+PK1H + PT2 + pk3+ pt3  +pk4 +pt4+plech2+ph22+pk22+pk12+ph12 + pkdk + pt3h+pk3h+pk5+pt5+pk6+pt6)
aux plecdivk=plecdivk


ph3 = -(phos-phos_tot)
aux ph3=ph3


###################### NUMERICS ####################################
@ total=200
# AUTO Settings
@ NTST=150, NMAX=2000, NPR=50, DS=-1e-5
@ PARMIN=0, PARMAX=0.5
@ AUTOXMIN=0, AUTOXMAX=1, AUTOYMIN=0, AUTOYMAX=2

done